FeralChild64
d489e7bf41
commit 2f27e29758da1f1ec965588c0712125051a6f71a Merge: ba722b1796b62fAuthor: FeralChild64 <you@example.com> Date: Tue Jan 28 17:34:53 2020 +0100 Merge branch 'master' into tape_redirect commit ba722b17e627af7dd067932688de0a3d86423e37 Author: FeralChild64 <you@example.com> Date: Tue Jan 28 17:28:19 2020 +0100 finished Mega65 variant of tape routines commit 47de685f2e08576504c5e00a5b7cb78498d22e72 Author: FeralChild64 <you@example.com> Date: Mon Jan 27 23:06:45 2020 +0100 compilation fix commit c3641acec049a7a6b53c35795b1f9e2df212cec2 Author: FeralChild64 <you@example.com> Date: Mon Jan 27 22:53:30 2020 +0100 dependencies fix commit dfad7a30bde043fa077005624dde1de4b72573b6 Merge: e4b0ec9e410bc0Author: FeralChild64 <you@example.com> Date: Mon Jan 27 21:25:49 2020 +0100 Merge branch 'master' into tape_redirect commit e4b0ec9c85861bde2ce52e0828d3bf895a681e17 Author: FeralChild64 <you@example.com> Date: Sat Jan 25 22:25:20 2020 +0100 initial attempt to move tape code to Mega65 extra ROM
74 lines
1.3 KiB
ArmAsm
74 lines
1.3 KiB
ArmAsm
// #LAYOUT# STD * #TAKE
|
|
// #LAYOUT# M65 KERNAL_1 #TAKE
|
|
// #LAYOUT# * * #IGNORE
|
|
|
|
//
|
|
// Tape (normal) helper routine - byte reading
|
|
//
|
|
// Returns byte in .A (also sotred in INBIT), Carry flag set = error
|
|
//
|
|
|
|
|
|
#if CONFIG_TAPE_NORMAL
|
|
|
|
|
|
tape_normal_get_byte:
|
|
|
|
// Init parity bit and canary bit
|
|
lda #$01
|
|
sta PRTY
|
|
lda #%01111111 // canary bit is 0
|
|
sta INBIT
|
|
|
|
// Now fetch individual bits
|
|
|
|
tape_normal_get_byte_loop:
|
|
|
|
jsr tape_normal_get_bit
|
|
bcs tape_normal_get_byte_error
|
|
beq !+
|
|
|
|
// Handle parity bit
|
|
lda #$01
|
|
eor PRTY
|
|
sta PRTY
|
|
|
|
sec
|
|
!: // moved bit state from Zero to Carry flag
|
|
|
|
ror INBIT // put the bit in
|
|
bcs tape_normal_get_byte_loop // loop if no canary bit reached
|
|
|
|
// Byte retrieved (on stack), now we need to validate the parity
|
|
|
|
jsr tape_normal_get_bit
|
|
bcs tape_normal_get_byte_error
|
|
beq !+
|
|
lda #$01
|
|
!:
|
|
eor PRTY
|
|
bne tape_normal_get_byte_error
|
|
|
|
// Checksum validated succesfully
|
|
|
|
ldx #$0B
|
|
// Carry already clear
|
|
|
|
// FALLTROUGH
|
|
|
|
tape_normal_get_byte_done:
|
|
|
|
stx VIC_EXTCOL
|
|
lda INBIT
|
|
rts
|
|
|
|
|
|
tape_normal_get_byte_error:
|
|
|
|
ldx #$09
|
|
sec // make sure Carry is set to indicate error
|
|
bcs tape_normal_get_byte_done
|
|
|
|
|
|
#endif
|