FeralChild64
d489e7bf41
commit 2f27e29758da1f1ec965588c0712125051a6f71a Merge: ba722b1796b62fAuthor: FeralChild64 <you@example.com> Date: Tue Jan 28 17:34:53 2020 +0100 Merge branch 'master' into tape_redirect commit ba722b17e627af7dd067932688de0a3d86423e37 Author: FeralChild64 <you@example.com> Date: Tue Jan 28 17:28:19 2020 +0100 finished Mega65 variant of tape routines commit 47de685f2e08576504c5e00a5b7cb78498d22e72 Author: FeralChild64 <you@example.com> Date: Mon Jan 27 23:06:45 2020 +0100 compilation fix commit c3641acec049a7a6b53c35795b1f9e2df212cec2 Author: FeralChild64 <you@example.com> Date: Mon Jan 27 22:53:30 2020 +0100 dependencies fix commit dfad7a30bde043fa077005624dde1de4b72573b6 Merge: e4b0ec9e410bc0Author: FeralChild64 <you@example.com> Date: Mon Jan 27 21:25:49 2020 +0100 Merge branch 'master' into tape_redirect commit e4b0ec9c85861bde2ce52e0828d3bf895a681e17 Author: FeralChild64 <you@example.com> Date: Sat Jan 25 22:25:20 2020 +0100 initial attempt to move tape code to Mega65 extra ROM
125 lines
2.1 KiB
ArmAsm
125 lines
2.1 KiB
ArmAsm
// #LAYOUT# STD * #TAKE
|
|
// #LAYOUT# M65 KERNAL_1 #TAKE
|
|
// #LAYOUT# * * #IGNORE
|
|
|
|
//
|
|
// Tape (normal) helper routine - data block (backup) reading
|
|
//
|
|
|
|
|
|
#if CONFIG_TAPE_NORMAL && !CONFIG_TAPE_NO_ERROR_CORRECTION
|
|
|
|
|
|
tape_normal_get_data_2:
|
|
|
|
// First check if there is a need to read anything
|
|
|
|
lda PTR1
|
|
beq tape_normal_get_data_2_log_checksum
|
|
|
|
// Read sync of the block
|
|
|
|
ldy #$09
|
|
jsr tape_normal_sync
|
|
bcs tape_normal_get_data_2_done // Carry already set, will indicate error
|
|
jsr tape_normal_get_marker
|
|
|
|
// FALLTROUGH
|
|
|
|
tape_normal_get_data_2_loop:
|
|
|
|
// Check if there are missing bytes to read
|
|
lda PTR1
|
|
cmp PTR2
|
|
beq tape_normal_get_data_2_log_checksum // branch if no more errors to correct
|
|
|
|
// Read missing bytes
|
|
|
|
jsr tape_normal_get_byte
|
|
bcc tape_normal_get_data_2_loop_byte_OK
|
|
|
|
// Problem reading a byte - just skip it
|
|
|
|
bcs tape_normal_get_data_2_loop_advance
|
|
|
|
tape_normal_get_data_2_loop_byte_OK:
|
|
|
|
jsr load_cmp_log_MEMUSS
|
|
beq tape_normal_get_data_2_loop_from_log // branch if byte from the log
|
|
|
|
jsr tape_normal_get_marker
|
|
bcs tape_normal_get_data_2_log_checksum // branch if end of blocks
|
|
bcc tape_normal_get_data_2_loop_advance
|
|
|
|
|
|
tape_normal_get_data_2_loop_from_log:
|
|
|
|
// This is a byte from the log
|
|
|
|
jsr tape_normal_get_marker
|
|
bcs !+
|
|
|
|
lda INBIT
|
|
ldy #$00
|
|
#if ROM_LAYOUT_M65
|
|
jsr tape_normal_byte_store
|
|
#else
|
|
sta (MEMUSS), y
|
|
#endif
|
|
!:
|
|
jsr tape_normal_update_checksum
|
|
|
|
// FALLTROUGH
|
|
|
|
tape_normal_get_data_2_loop_advance:
|
|
|
|
// Advance pointer
|
|
#if !HAS_OPCODES_65CE02
|
|
jsr lvs_advance_MEMUSS
|
|
#else
|
|
inw MEMUSS+0
|
|
#endif
|
|
|
|
jmp tape_normal_get_data_2_loop
|
|
|
|
|
|
tape_normal_get_data_2_log_checksum:
|
|
|
|
lda PTR1
|
|
cmp PTR2
|
|
bne tape_normal_get_data_2_done // Carry already set
|
|
|
|
// Validate checksum
|
|
|
|
lda RIPRTY
|
|
cmp #$01 // sets Carry if checksum verification fails
|
|
|
|
// FALLTROUGH
|
|
|
|
tape_normal_get_data_2_done:
|
|
|
|
rts
|
|
|
|
|
|
load_cmp_log_MEMUSS:
|
|
|
|
ldx PTR2
|
|
lda STACK+0, x
|
|
cmp MEMUSS+0
|
|
bne !+
|
|
|
|
lda STACK+1, x
|
|
cmp MEMUSS+1
|
|
bne !+
|
|
|
|
// MEMUSS matches address from the log
|
|
|
|
inc PTR2
|
|
inc PTR2
|
|
lda #$00 // to set Zero flag
|
|
!:
|
|
rts
|
|
|
|
|
|
#endif
|